$!-----------------------------------------------------------------------------
$! WCME_SETUP.COM
$!
$! P1 should be "WASD" (default) or "APACHE".
$!
$! 23-MAY-2017  MGD  initial
$!-----------------------------------------------------------------------------
$ say = "write sys$output"
$ set noon
$!
$ procedure = f$element(0,";",f$environment("procedure"))
$ write sys$output f$fao("!#*>", 78-f$length(procedure)) + " " + procedure 
$!
$ P1 = f$edit(P1, "upcase")
$!
$ if f$trnlnm("WASD_FILE_DEV") .nes. "" then @wasd_file_dev
$!
$ if P1 .eqs. ""
$ then
$    if f$trnlnm("WASD_ROOT") .nes. "" then P1 = "WASD"
$    if (P1 .eqs. "" .and. f$trnlnm("APACHE$ROOT") .nes. "") -
        then P1 = "APACHE"
$ endif
$!
$ if P1 .eqs. "WASD"
$ then
$    wasd_root = f$trnlnm("WASD_ROOT")
$    if wasd_root .eqs. "" then exit 44
$    wcme_root = wasd_root - ".]" + ".LOCAL.WCME.]"
$ endif
$!
$ if P1 .eqs. "APACHE"
$ then
$    apache_common = f$trnlnm("APACHE$COMMON")
$    if apache_common .eqs. "" then exit 44
$    wcme_root = apache_common - ".]" + ".WCME.]"
$ endif
$!
$ if P1 .nes. "WASD" .and. P1 .nes. "APACHE" then exit 44
$!
$ define /system /trans=concealed /executive /nolog WCME_ROOT 'wcme_root'
$!
$ create /directory /protect=(s:rwe,o:rwe,g,w) WCME_ROOT:[etc]
$ create /directory /protect=(s:rwe,o:rwe,g,w) WCME_ROOT:[log]
$ create /directory /protect=(s:rwe,o:rwe,g,w) WCME_ROOT:[priv]
$ create /directory /protect=(s:rwe,o:rwe,g,w) WCME_ROOT:[ssl]
$ create /directory /protect=(s:rwe,o:rwe,g,w) WCME_ROOT:[www]
$ if f$length(f$search("WCME_ROOT:[000000]*.*")) .eq. 0 then exit 44
$!
$ write sys$output f$fao("!#*<", 78-f$length(procedure)) + " " + procedure 
$!-----------------------------------------------------------------------------