$!-----------------------------------------------------------------------------
$! WCME_LOAD.COM
$!
$! When a certificate is sucessfully renewed execute this to load.
$! Will take a parameter of "WASD" or "APACHE" to load one or the other on
$! a system supporting both, otherwise one or the other or both in the single
$! execution. 
$!
$! 20-JUN-2017  MGD  initial
$!-----------------------------------------------------------------------------
$ set noon
$!
$ p1 = f$edit(p1,"upcase")
$!
$ if p1 .eqs. "" .or. p1 .eqs. "WASD"
$ then
$    if f$trnlnm("WASD_ROOT","lnm$system") .nes. ""
$    then
$       set process /privilege=SYSPRV
$       httpd = "$wasd_exe:httpd_ssl.exe"
$       write sys$output "$ httpd /version"
$       httpd /version
$       version = f$integer(f$element(0,".",HTTPD_VERSION)) * 100 + -
                  f$integer(f$element(1,".",HTTPD_VERSION)) * 10
$       if version .ge. 1110
$       then
$!         (WASD v11.1.0 or later)
$          write sys$output "$ httpd_ssl /do=ssl=cert=load" 
$          httpd /do=ssl=cert=load
$       else
$!         (earlier than WASD v11.1.0)
$          write sys$output "$ httpd_ssl /do=restart=now" 
$          httpd /do=restart=now
$       endif
$       delete /symbol /local httpd
$       if p1 .nes. "" then exit
$    endif
$ endif
$!
$ if p1 .eqs. "" .or. p1 .eqs. "APACHE"
$ then
$    if f$trnlnm("APACHE$COMMON","lnm$system") .nes. ""
$    then
$       set process /privilege=(IMPERSONATE,SYSPRV)
$       write sys$output "$ mcr apache$common:[000000]apache$httpd.exe -v"
$       mcr apache$common:[000000]apache$httpd.exe -v
$       write sys$output "$ @sys$startup:apache$startup restart"
$       @sys$startup:apache$startup restart
$       if p1 .nes. "" then exit
$    endif
$ endif
$!
$ if p1 .nes. "" then exit 44
$!-----------------------------------------------------------------------------