$!-----------------------------------------------------------------------------
$! INSTALL.COM
$!
$! Install and remove the PERLRTE and example scripts.
$!
$! 02-JAN-2003  MGD  initial
$!-----------------------------------------------------------------------------
$ say = "write sys$output"
$ ss$_abort = 44
$ copy = "copy/log"
$ delete = "delete/log"
$ archName = f$edit(f$getsyi("arch_name"),"UPCASE")
$ if archName .eqs. "ALPHA" then archName = "axp"
$!
$ if p1 .nes. "REMOVE"
$ then
$    type sys$input
                           ***********************
                           *  INSTALL WASD PERL  *
                           ***********************

This procedure installs the PERLRTE.EXE and example scripts.  It prompts for
and does these separately so that the examples may be evaluated and later
removed leaving the PERLRTE available for scripting.

This installation can be removed using  $ @INSTALL REMOVE

$    response = ""
$    read sys$command /prompt="Continue? [N]: " response
$    say ""
$    if .not. response then exit
$!
$    response = ""
$    read sys$command /prompt="Install PERLRTE.EXE interpreter? [N]: " response
$    say ""
$    if response
$    then
$       copy ht_exe:perlrte.exe wasd_root:['archName'-bin]
$       say ""
$    endif
$!
$    response = ""
$    read sys$command /prompt="Install PERLRTE example scripts? [N]: " response
$    say ""
$    if response
$    then
$       copy wasd_root:[src.perl]perlrte_example*.pl wasd_root:[cgi-bin]
$       copy wasd_root:[src.perl]perlrte_example*.com wasd_root:[cgi-bin]
$       say ""
$    endif
$!
$    response = ""
$    read sys$command /prompt="Install CGIPLUS.pm example scripts? [N]: " response
$    say ""
$    if response
$    then
$       copy wasd_root:[src.perl]cgipluspm_example*.pl wasd_root:[cgi-bin]
$       say ""
$    endif
$!
$ endif
$!
$ if p1 .eqs. "REMOVE"
$ then
$    type sys$input
                           **********************
                           *  REMOVE WASD PERL  *
                           **********************

This procedure removes the PERLRTE.EXE and example scripts.  It prompts for and
does these separately so that the examples may be removed leaving the PERLRTE
available for scripting.

Note: it does not delete the WASD_ROOT:[SRC.PERL] tree.

$    read sys$command /prompt="Continue? [N]: " response
$    say ""
$    if .not. response then exit
$    response = ""
$    read sys$command /prompt="Remove PERLRTE.EXE interpreter? [N]: " response
$    say ""
$    if response
$    then
$       delete wasd_root:['archName'-bin]perlrte.exe;*
$       say ""
$    endif
$!
$    response = ""
$    read sys$command /prompt="Remove PERLRTE example scripts? [N]: " response
$    say ""
$    if response
$    then
$       delete wasd_root:[cgi-bin]perlrte_example*.pl;*
$       delete wasd_root:[cgi-bin]perlrte_example*.com;*
$       say ""
$    endif
$!
$    response = ""
$    read sys$command /prompt="Remove CGIPLUS.pm example scripts? [N]: " response
$    say ""
$    if response
$    then
$       delete wasd_root:[cgi-bin]cgipluspm_example*.pl;*
$       say ""
$    endif
$!
$ endif
$!
$ type sys$input
                            *********************
                            *  C O M P L E T E  *
                            *********************

$ exit
$!-----------------------------------------------------------------------------