$!-----------------------------------------------------------------------------
$! BUILD_MEMBUFDEMO.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$! P2 == APACHE for apache module build
$!
$! 27-OCT-2024  MGD  modify for Apache build
$! 12-OCT-2017  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ @WASD_ROOT:[SRC]ARCHER.COM "MEMBUFDEMO"
$!
$ DEFINES = " /DEFINE=(__VMS_VER=70000000,__CRTL_VER=70000000)"
$ IF P2 .EQS. "APACHE" THEN DEFINES = DEFINES - ")" + ",APACHE_MOD)"
$ INCLUDES = ""
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW,IMPLICITFUNC))"
$ CC_OPTIONS = "/DECC /NODEBUG /OPTIMIZE /STAND=RELAXED_ANSI " +-
               "/PREFIX=ALL /NAMES=AS_IS" +-
               INCLUDES + DEFINES + WARNINGS
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    IF P2 .EQS. "APACHE"
$    THEN
$       SET VERIFY
$       CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR'MOD_MEMBUFDEMO MEMBUFDEMO + -
           APACHE$ROOT:[INCLUDE]APACHE$LIBRARY.TLB/LIB
$!      'F$VERIFY(0)
$    ELSE
$       SET VERIFY
$       CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' MEMBUFDEMO
$!      'F$VERIFY(0)
$    ENDIF
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    SET NOON
$    IF P2 .EQS. "APACHE"
$    THEN
$       SET VERIFY
$       LINK /NOTRACEBACK /EXECUTABLE=WASD_EXE:MOD_MEMBUFDEMO.EXE -
             'OBJECT_DIR'MOD_MEMBUFDEMO/SHARE,SYS$INPUT/OPTIONS
CASE_SENSITIVE=YES
SYMBOL_VECTOR=(membufdemo_module=DATA)
APACHE$APR_SHR/share
APACHE$HTTPD_SHR/share
$!      'F$VERIFY(0)
$    ELSE
$       SET VERIFY
$       LINK /NOTRACEBACK /EXECUTABLE=WASD_EXE:MEMBUFDEMO.EXE -
             'OBJECT_DIR'MEMBUFDEMO,MEMBUFLIB
$!      'F$VERIFY(0)
$    ENDIF
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'OBJECT_DIR'
$!
$!-----------------------------------------------------------------------------