$!-----------------------------------------------------------------------------
$! BUILD_GSOAPRTE.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$! P1 == REFRESH copies STDSOAP2.H and APACHE_GSOAP.H then compiles
$!
$! 08-JUN-2013  MGD  refresh headers
$! 15-MAR-2010  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "Building ""GSOAPRTE""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ ARCH_NAME = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
$ IF ARCH_NAME .EQS. "ALPHA" THEN ARCH_NAME = "AXP"
$!
$ DEFINES = ""
$!! INCLUDE = " /INCLUDE=([],GSOAP$ROOT:[INCLUDES])"
$ INCLUDE = " /INCLUDE=([])"
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW))"
$!
$ IF F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE") .EQS. "VAX"
$ THEN
$    WRITE SYS$OUTPUT "gSOAP NOT SUPPORTED on VAX!"
$    EXIT 44
$ ELSE
$    CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
                  INCLUDE + DEFINES + WARNINGS
$ ENDIF
$!
$ IF F$SEARCH("OBJ_''ARCH_NAME'.DIR") .EQS. "" -
     THEN CREATE /DIR [.OBJ_'ARCH_NAME']
$ OBJECT_DIR = "[.OBJ_''ARCH_NAME']"
$!
$ IF P1 .EQS. "REFRESH"
$ THEN
$    SET VERIFY
$    COPY GSOAP$ROOT:[INCLUDE]STDSOAP2.H *
$    COPY GSOAP$ROOT:[INCLUDE]APACHE_GSOAP.H *
$!   'F$VERIFY(0)
$    P1 = "BUILD"
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' GSOAPRTE
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' CGIPLUS_GSOAP
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    SET NOON
$    SET VERIFY
$    LINK /EXECUTABLE=WASD_EXE:GSOAPRTE.EXE -
          'OBJECT_DIR'GSOAPRTE
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'OBJECT_DIR'
$!
$!-----------------------------------------------------------------------------