$!-----------------------------------------------------------------------------
$! BUILD_ONE.COM
$!
$! P1 == program name
$! P2 == LINK or BUILD or empty (builds)
$!
$! 30-MAY-1998  MGD  initial re-development
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ @WASD_ROOT:[SRC]ARCHER.COM "''P1'"
$!
$ DEFINES = " /DEFINE=(__VMS_VER=70000000,__CRTL_VER=70000000)"
$ INCLUDES = " /INCLUDE=([SRC.MISC])"
$!
$ LINK_OPTIONS = F$SEARCH("''P1'_''ARCH_NAME'.OPT")
$ IF LINK_OPTIONS .NES. "" -
     THEN LINK_OPTIONS = "," + F$ELEMENT(0,";",LINK_OPTIONS) + "/OPTIONS"
$!
$ CC_OPTIONS = "/DECC /STAND=RELAXED_ANSI /PREFIX=ALL /NAMES=AS_IS " +-
               "/WARNING=DISABLE=(PREOPTW)" +-
               DEFINES + INCLUDES
$!
$ IF P2 .EQS. "" .OR. P2 .EQS. "BUILD" .OR. P2 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='WASD_OBJ_DIR' 'P1'
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P2 .EQS. "" .OR. P2 .EQS. "BUILD" .OR. P2 .EQS. "LINK"
$ THEN
$    CGILIB_OLB = "[SRC.MISC.OBJ_''WASD_ARCH_NAME']CGILIB.OLB"
$    SET NOON
$    SET VERIFY
$    LINK /EXECUTABLE=WASD_EXE:'P1'.EXE -
     'WASD_OBJ_DIR''P1','CGILIB_OLB'/LIBRARY'LINK_OPTIONS'
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'WASD_OBJ_DIR'
$!
$!-----------------------------------------------------------------------------