$ write sys$output "content-type: text/plain"
$ write sys$output ""
$ if f$extract(0,7,f$process()) .eqs. "/phprte"
$ then
$    spawn /nowait @cgi-bin:[000000]phprte_mvb.com
$    wait 00:00:10
$    stop/id=0
$ endif
$!-----------------------------------------------------------------------------
$! PHPRTE.COM
$!
$! Define the PHP logical name environment.
$! Default are the VSI V8 logical names.
$! This DCL procedure is only required if NOT using VSI PHP.
$! When using an alternate PHP V8 engine copy into cgi_bin: and edit.
$! Custom logical names may be used by assigning values to symbol root and shr.
$!
$! Copyright (C) 2002-2024 Mark G. Daniel
$! This package comes with ABSOLUTELY NO WARRANTY.
$! This is free software, and you are welcome to redistribute it.
$!
$! 19-JUL-2025  MGD  fix brain-dead Mark Berryman PHPWASD support
$! 02-AUG-2024  MGD  adapt for VSI PHP beginning with V8.0
$!-----------------------------------------------------------------------------
$!
$ root = ""
$ shr = ""
$!
$!(to force WASD phpRTE uncomment the next line)
$!! root = "!"
$!
$ if root .eqs. "" .and. root .nes. "!"
$ then
$    if f$search("cgi_exe:phpwasd.exe") .nes. "" .and. -
        f$search("cgi_exe:phpshr.exe") .nes. ""
$    then
$!      (accomodate Mark Berryman PHPWASD environment)
$       root = f$trnlnm("cgi_exe") - "]" + ".]"
$       phpwasd = "$cgi_exe:phpwasd.exe"
$       define /job phpwasdshr "cgi_exe:phpshr.exe"
$       define /job /translation=concealed php_root 'root'
$       if f$mode() .eqs. "INTERACTIVE" then show log php* /job /full
$       phpwasd
$       exit
$    endif
$ endif
$!
$! (Standard VSI PHP V8)
$!
$ if root .eqs. "" .or. root .eqs. "!"
$ then
$!   (default VSI PHP$ROOT)
$    root = f$trnlnm("sys$common") - ".]" + ".php.]
$ endif
$ if shr .eqs. ""
$ then
$!   (default VSI PHP$SHR)
$    shr = f$trnlnm("php$shr")
$    phprte = "$cgi_exe:phprte.exe"
$ endif
$ define /job /translation=concealed php$root 'root'
$ define /job php$shr 'shr'
$ if f$mode() .eqs. "INTERACTIVE" then show log php* /job /full
$ phprte
$!-----------------------------------------------------------------------------