$!-----------------------------------------------------------------------------
$! WUCME_STARTUP.COM
$!
$! To have relevant logical names automatically defined then assign local
$! symbols before calling the procedure.  For example:
$!
$!   $ WUCME_MAIL = "SYSTEM,mark.daniel@wasd.vsm.com.au"
$!   $ WUCME_OPCOM = "CENTRAL,OPER2"
$!   $ WUCME_VERBOSE = "*"
$!   $ @WASD_ROOT:[SRC.WUCME]WUCME_STARTUP.COM
$!
$! Symbols supported in this fashion:
$!
$!   WUCME_CHALLENGE  specify which challenge is preferred
$!   WUCME_LOAD       action to load renewed certificate (1 or 2 values)
$!   WUCME_MAIL       reporting email address(es) 
$!   WUCME_OPCOM      reporting OPCOM destination(s)
$!   WUCME_SETPRV     install image with SETPRV
$!   WUCME_VERBOSE    make wuCME very chatty
$!
$! Logical name values containing quotation marks must be escaped (doubled-up).
$!
$! 25-SEP-2024  MGD  provide for WASD v12.2.5 and WUCME_CHALLENGE
$! 18-DEC-2020  MGD  provide issuer verification via logical name
$! 03-JUN-2020  MGD  provide SETPRV
$! 18-DEC-2019  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ on error then continue
$ procedure = f$element(0,";",f$environment("procedure"))
$ write sys$output f$fao("!#*>", 78-f$length(procedure)) + " " + procedure
$!
$ if f$trnlnm("WASD_FILE_DEV") .nes. "" then @wasd_file_dev
$!
$ if f$type(WUCME_LOAD) .nes. "" then -
     define /system /executive /nolog WUCME_LOAD "''WUCME_LOAD'"
$!
$ if f$type(WUCME_MAIL) .nes. "" then -
     define /system /executive /nolog WUCME_MAIL "''WUCME_MAIL'"
$!
$ if f$type(WUCME_OPCOM) .nes. "" then -
     define /system /executive /nolog WUCME_OPCOM "''WUCME_OPCOM'"
$!
$ if f$type(WUCME_SETPRV) .nes. ""
$    then privs = "(sysprv,syslck,setprv)"
$    else privs = "(sysprv,syslck)"
$ endif
$!
$ if f$type(WUCME_VERBOSE) .nes. "" then -
     define /system /executive /nolog WUCME_VERBOSE "''WUCME_VERBOSE'"
$!
$ if f$type(WUCME_CHALLENGE) .nes. ""
$ then
$    define /system /executive /nolog WUCME_CHALLENGE "''WUCME_CHALLENGE'"
$ else
$    define /system /executive /nolog WUCME_CHALLENGE "http-01"
$    if f$search("wasd_exe:httpd_ssl.exe") .nes. ""
$       then mcr wasd_exe:httpd_ssl /version /output=nl:
$       else mcr wasd_exe:httpd /version /output=nl:
$    endif
$    version = f$element(0,".",HTTPD_VERSION) * 10000
$    version = version + f$element(1,".",HTTPD_VERSION) * 100
$    version = version + f$element(2,".",HTTPD_VERSION)
$    if version .ge. 120205
$    then
$       if f$search("cgi_bin:acme_tls_1.com") .eqs. ""
$       then
$          write sys$output "ERROR: did not find CGI_BIN:ACME_TLS_1.COM"
$       else
$          define /system /executive /nolog WUCME_CHALLENGE "tls-alpn-01"
$       endif
$    endif
$ endif
$!
$ script = "cgi-bin:[000000]wucme.exe"
$ if f$file(script,"known") then install remove 'script'
$ install add /open /header /share 'script' /priv='privs'
$!
$ write sys$output f$fao("!#*<", 78-f$length(procedure)) + " " + procedure 
$!
$!-----------------------------------------------------------------------------