$!-----------------------------------------------------------------------------
$! INSTALL.COM
$!
$! Install and remove the PERLRTE and example scripts.
$!
$! 02-JAN-2003  MGD  initial
$!-----------------------------------------------------------------------------
$ say = "write sys$output"
$ ss$_abort = 44
$ copy = "copy/log"
$ delete = "delete/log"
$ archName = f$edit(f$getsyi("arch_name"),"UPCASE")
$ if archName .eqs. "ALPHA" then archName = "axp"
$!
$ if f$search("ht_exe:sechan.exe") .eqs. ""
$ then
$    type sys$input

                           ***********************
                           *  WASD 8.1 OR LATER  *
                           ***********************

This kit is only suitable for WASD 8.1 or later.
Please update your site (for this and other reasons) ASAP!

$    exit ss$_abort
$ endif
$!
$ type sys$input

                   Copyright (C) 2000-2008 Mark G.Daniel.
 This package (all associated programs), comes with ABSOLUTELY NO WARRANTY.
   This is free software, and you are welcome to redistribute it under the
 conditions of the GNU GENERAL PUBLIC LICENSE, version 3, or any later version.

$!
$ if p1 .nes. "REMOVE"
$ then
$    type sys$input
                           ***********************
                           *  INSTALL WASD PERL  *
                           ***********************

This procedure installs the PERLRTE.EXE and example scripts.  It prompts for
and does these separately so that the examples may be evaluated and later
removed leaving the PERLRTE available for scripting.

This installation can be removed using  $ @INSTALL REMOVE

$    response = ""
$    read sys$command /prompt="Continue? [N]: " response
$    say ""
$    if .not. response then exit
$!
$    response = ""
$    read sys$command /prompt="Install PERLRTE.EXE interpreter? [N]: " response
$    say ""
$    if response
$    then
$       copy ht_exe:perlrte.exe ht_root:['archName'-bin]
$       say ""
$    endif
$!
$    response = ""
$    read sys$command /prompt="Install PERLRTE example scripts? [N]: " response
$    say ""
$    if response
$    then
$       copy ht_root:[src.perl]perlrte_example*.pl ht_root:[cgi-bin]
$       copy ht_root:[src.perl]perlrte_example*.com ht_root:[cgi-bin]
$       say ""
$    endif
$!
$    response = ""
$    read sys$command /prompt="Install CGIPLUS.pm example scripts? [N]: " response
$    say ""
$    if response
$    then
$       copy ht_root:[src.perl]cgipluspm_example*.pl ht_root:[cgi-bin]
$       say ""
$    endif
$!
$ endif
$!
$ if p1 .eqs. "REMOVE"
$ then
$    type sys$input
                           **********************
                           *  REMOVE WASD PERL  *
                           **********************

This procedure removes the PERLRTE.EXE and example scripts.  It prompts for and
does these separately so that the examples may be removed leaving the PERLRTE
available for scripting.

Note: it does not delete the HT_ROOT:[SRC.PERL] tree.

$    read sys$command /prompt="Continue? [N]: " response
$    say ""
$    if .not. response then exit
$    response = ""
$    read sys$command /prompt="Remove PERLRTE.EXE interpreter? [N]: " response
$    say ""
$    if response
$    then
$       delete ht_root:['archName'-bin]perlrte.exe;*
$       say ""
$    endif
$!
$    response = ""
$    read sys$command /prompt="Remove PERLRTE example scripts? [N]: " response
$    say ""
$    if response
$    then
$       delete ht_root:[cgi-bin]perlrte_example*.pl;*
$       delete ht_root:[cgi-bin]perlrte_example*.com;*
$       say ""
$    endif
$!
$    response = ""
$    read sys$command /prompt="Remove CGIPLUS.pm example scripts? [N]: " response
$    say ""
$    if response
$    then
$       delete ht_root:[cgi-bin]cgipluspm_example*.pl;*
$       say ""
$    endif
$!
$ endif
$!
$ type sys$input
                            *********************
                            *  C O M P L E T E  *
                            *********************

$ exit
$!-----------------------------------------------------------------------------