$!-----------------------------------------------------------------------------
$! BUILD_INTRUSPECT.COM
$!
$! 25-MAR-2015  MGD  initial
$!-----------------------------------------------------------------------------
$ ON CONTROLY THEN EXIT 44
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "Building ""INTRUSPECT""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ ARCH_NAME = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
$ IF ARCH_NAME .EQS. "ALPHA" THEN ARCH_NAME = "AXP"
$!
$ DEFINES = "/DEFINE=(__VMS_VER=70300000,__CRTL_VER=70300000)"
$ WARNINGS=  "/WARNING=(DISABLE=(PREOPTW,IMPLICITFUNC,ADDRCONSTEXT))"
$!
$ IF F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE") .EQS. "VAX"
$ THEN
$    CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI ''DEFINES'''WARNINGS'"
$ ELSE
$    CC_OPTIONS = "/DECC /OPTIMIZE /FLOAT=IEEE /IEEE=DENORM " +-
                  "/STAND=RELAXED_ANSI ''DEFINES'''WARNINGS'"
$ ENDIF
$!
$ IF F$SEARCH("OBJ_''ARCH_NAME'.DIR") .EQS. "" -
     THEN CREATE /DIR [.OBJ_'ARCH_NAME']
$ OBJECT_DIR = "[.OBJ_''ARCH_NAME']"
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' INTRUSPECT.C
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' WSLIB.C
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    IF ARCH_NAME .EQS. "VAX"
$       THEN SYSEXE = ""
$       ELSE SYSEXE = "/SYSEXE"
$    ENDIF
$    SET NOON
$    SET VERIFY
$    LINK /NOTRACEBACK 'SYSEXE' -
          /EXECUTABLE='OBJECT_DIR'INTRUSPECT.EXE -
          'OBJECT_DIR'INTRUSPECT,WSLIB
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'OBJECT_DIR'
$!
$!-----------------------------------------------------------------------------