$!-----------------------------------------------------------------------------
$! BUILD_HYPERSPIXX.COM
$! Builds the HYPERSPIXX utility
$!
$! 06-FEB-2018  MGD  fixes to [...]DESCRIP.MMS per JMB
$!                   try, try again to [.LIB]BUILD.COM
$! 20-MAY-2011  MGD  /FLOAT /IEEE on non-VAX and Alpha (i.e. Itanium at date)
$!                   (Alpha remains at default float due to library builds!)
$!                   modify all .MMS to disable use of system-wide libraries
$!                   (force build and link of local-to-hyperspixx libraries)
$! 30-OCT-2000  JFP  initial development
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "Building ""HYPERSPIXX""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ ARCH_NAME = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
$ IF ARCH_NAME .EQS. "ALPHA" THEN ARCH_NAME = "AXP"
$!
$ IF F$SEARCH("OBJ_''ARCH_NAME'.DIR") .EQS. "" -
     THEN CREATE /DIR [.OBJ_'ARCH_NAME']
$ OBJECT_DIR = "[.OBJ_''ARCH_NAME']"
$!
$ DEFINES = " /DEFINE=(__VMS,__VMS_VER=70000000," +-
                       "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE)"
$! DEFINES = "/DEFINE=(__VMS,CGILIB_OBJECT_MODULE)"
$ INCS = "/Include = ([], LibGDCHART:, LibJPEG:, LibPNG:, LibZ:, LibGD:)"
$!
$ IF F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE") .EQS. "VAX" .OR. -
     F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE") .EQS. "ALPHA"
$ THEN
$    CC_OPTIONS = "/PREFIX=ALL'DEFINES' /OBJECT=''OBJECT_DIR' " +-
                  "/WARN=(DISABLE=PREOPTW)"
$    LINK_OPTIONS = "HYPERSPIXX_VAX.OPT/OPTIONS"
$ ELSE
$    CC_OPTIONS = "/PREFIX=ALL'DEFINES'/OBJECT=''OBJECT_DIR' " +-
                  "/FLOAT=IEEE /WARN=(DISABLE=PREOPTW)"
$    LINK_OPTIONS = "HYPERSPIXX_NONVAX.OPT/OPTIONS"
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LIB"
$ THEN
$    WRITE SYS$OUTPUT ""
$    WRITE SYS$OUTPUT "Building ""GDCHART""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$    SET NOON
$    set def [.lib]
$    @build
$    set def [-]
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS''INCS' CGILIB
$    CC 'CC_OPTIONS''INCS' hyperSPIxx
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    SET NOON
$    SET VERIFY
$    LINK /NOTRACE /EXECUTABLE=HT_EXE:HYPERSPIXX.EXE -
     'OBJECT_DIR'hyperspixx,'OBJECT_DIR'CGILIB, -
     []'LINK_OPTIONS'
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'OBJECT_DIR'
$!-----------------------------------------------------------------------------