$!-----------------------------------------------------------------------------
$! BUILD_CGIPLUSTEST.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$! P2 == Optional location of CGILIB object module (defaults to [.MISC])
$!
$! 19-MAR-2023  MGD  adapt for building Apache mod_cgiplustest
$! 19-OCT-2009  MGD  re-development
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ @WASD_ROOT:[SRC]ARCHER.COM "CGIPLUSTEST"
$!
$ DEFINES = " /DEFINE=(__VMS_VER=70000000," +-
                       "__CRTL_VER=70000000,CGILIB_OBJECT_MODULE)"
$!
$ IF P2 .EQS. "APACHE"
$ THEN
$    DEFINES = DEFINES - ")" + ",APACHE_MOD)"
$ ENDIF
$!
$ INCLUDES = " /INCLUDE=[SRC.MISC]"
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW,IMPLICITFUNC))"
$ CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
               "/NAMES=(AS_IS,SHORTENED)" +-
               INCLUDES + DEFINES + WARNINGS
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    IF P2 .EQS. "APACHE"
$    THEN
$       SET VERIFY
$       CC 'CC_OPTIONS' /OBJECT='WASD_OBJ_DIR' CGIPLUSTEST + -
           APACHE$ROOT:[INCLUDE]APACHE$LIBRARY.TLB/LIB
$!      'F$VERIFY(0)
$    ELSE
$       SET VERIFY
$       CC 'CC_OPTIONS' /OBJECT='WASD_OBJ_DIR' CGIPLUSTEST
$!      'F$VERIFY(0)
$    ENDIF
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    CGILIB_OBJ = "[SRC.MISC.OBJ_''WASD_ARCH_NAME']CGILIB.OBJ"
$    SET NOON
$    IF P2 .EQS. "APACHE"
$    THEN
$       SET VERIFY
$       LINK /EXECUTABLE=WASD_EXE:MOD_CGIPLUSTEST.EXE -
        'WASD_OBJ_DIR'CGIPLUSTEST/share,'CGILIB_OBJ'/share,SYS$INPUT/OPTIONS
CASE_SENSITIVE=YES
SYMBOL_VECTOR=(cgiplustest_module=DATA)
APACHE$APR_SHR/share
APACHE$HTTPD_SHR/share
$!      'F$VERIFY(0)
$    ELSE
$       SET VERIFY
$       LINK /EXECUTABLE=WASD_EXE:CGIPLUSTEST.EXE -
        'WASD_OBJ_DIR'CGIPLUSTEST,'CGILIB_OBJ'
$!      'F$VERIFY(0)
$    ENDIF
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'WASD_OBJ_DIR'
$!
$!-----------------------------------------------------------------------------