In the absence of a default node entity, if no node is specified
    in an NCL command, then the default node-id is 0, which represents
    the local node.

    You can specify a node-id in an NCL command in various ways, using
    either a node name or address.  Under certain conditions, the
    unqualified node name (often identical to the node synonym) may be
    used in an NCL command as the node-id.

1  –  Addresses

    If the name service is interrupted or unavailable, you can
    still reach remote nodes to perform management functions. You can
    use the remote node's Phase IV address (if the remote node is
    configured to have one), or the remote node's NSAP. Refer to the
    "Understanding and Creating NSAP Addresses" chapter in the
    DECnet-Plus Planning Guide for the Tru64 UNIX or OpenVMS NSAP
    format to use.

    For example, the following commands all perform the same function:

    ncl> show node 12.5 routing circuit syn-0-0

    For a Tru64 UNIX system:

    ncl> show node 49::00-0C:AA-00-04-00-05-30:20 routing -
    _ncl> circuit syn-0-0

    For an OpenVMS system:

    ncl> show node net$49000CAA000400053020 routing circuit syn-0-0

    If both the local and remote nodes are configured to run
    DECnet over TCP/IP (RFC 1859), you may refer to the remote node
    using the IP address as in:

    ncl> show node 16.78.232.13 all

2  –  Names

    Node names can be specified in different ways depending upon
    the directory service(s) you are using.

    If the local node is configured to use the DECdns name service
    and the remote node is correctly registered in the DECdns
    namespace, you may refer to the node using a DECdns fullname,
    as in:

    ncl> show node NS:.lkg.remotenode all

    If the local node is configured to use the LOCAL name service
    and the remote node is correctly registered in the LOCAL
    namespace, you may choose to use the LOCAL fullname, as in:

    ncl> show node LOCAL:.remotenode all

    If both the local and remote nodes are running DECnet over
    TCP/IP (RFC 1859) and the remote host name is somehow
    translatable (perhaps using the Hosts Database or DNS/BIND),
    you may refer to the remote node using the DOMAIN fullname,
    as in:

    ncl> show node DOMAIN:remotenode.lkg.dec.com all

3  –  Unqualified Names and Node Synonyms

    A node synonym is a Phase IV-style node name, between 1 and 6
    characters long, that is unique within the namespace.  This
    node synonym is required for Phase IV applications that can
    handle only a maximum of 6-character node names.

    An unqualified name is the final simplename -- that portion
    of the DECdns or LOCAL full name following the last "."
    Although this unqualified name is usually identical to the
    node synonym, it is not required to be identical to the node
    synonym.

    An unqualified name may be substituted for a full name in
    an NCL command only when the remote node specified in the
    command and the local node use the same primary naming
    service and their full names are identical except for the
    unqualified names themselves.

    For example, in the following cases:

                        LOCAL NODE           REMOTE NODE

    Full name:          ns:.lkg.localnode    ns:.lkg.remotenode
    Unqualified name:   localnode            remotenode
    Synonym:            locnod               remnod

    Full name:          local:.localnode     local:.remotenode
    Unqualified name:   localnode            remotenode
    Synonym:            locnod               remnod

    You can substitute the unqualified name for the full name in
    the NCL command:

    ncl> set event dispatcher outbound stream ost_1 -
        sink node remotenode

    However, for the following examples:

                        LOCAL NODE           REMOTE NODE

    Full name:          ns:.uct.localnode    ns:.lkg.remotenode
    Unqualified name:   localnode            remotenode
    Synonym:            locnod               remnod

    Full name:          ns:.localnode        local:.remotenode
    Unqualified name:   localnode            remotenode
    Synonym:            locnod               remnod

    Full name:          local:.uct.localnode local:.remotenode
    Unqualified name:   localnode            remotenode
    Synonym:            locnod               remnod

    You must specify the full name for the remote node in the
    NCL command:

    ncl> set event dispatcher outbound stream ost_1 -
    _ncl> sink node ns:.lkg.remotenode

    Or, on a Tru64 UNIX system:

    ncl> set session control proxy dth source end user = -
    _ncl> { [ node=local:.remotenode , end user=uic=[0,0]dan ] }

    The node synonym cannot be substituted for a full name in
    the NCL command. However, in most cases since the unqualified
    name and the node synonym are usually identical, it may
    appear that the synonym substitution was successful.